@echo off
chcp 65001 >nul
cd /d "%~dp0"

if not exist "zfile\zfile-pro.exe" (
    echo(错误: 找不到 zfile\zfile-pro.exe
    echo(
    echo(按任意键退出...
    pause >nul
    exit /b 1
)

set "ZFILE_VERSION=未知"
set "ZFILE_COMMIT=未知"
set "ZFILE_BUILD_TIME=未知"
for /f "tokens=1,* delims==" %%A in ('"zfile\zfile-pro.exe" --version --details 2^>nul') do (
    if /i "%%A"=="version" set "ZFILE_VERSION=%%B"
    if /i "%%A"=="gitCommitId" set "ZFILE_COMMIT=%%B"
    if /i "%%A"=="buildTime" set "ZFILE_BUILD_TIME=%%B"
)

if "%ZFILE_VERSION%"=="未知" (
    echo(错误: 无法读取程序版本，当前二进制可能是旧版本或文件不完整
    echo(
    echo(按任意键退出...
    pause >nul
    exit /b 1
)

echo(zfile-pro 版本信息
echo(----------------------------------------
echo(  程序版本 : %ZFILE_VERSION%
echo(  Git 提交 : %ZFILE_COMMIT%
echo(  构建时间 : %ZFILE_BUILD_TIME%
echo(----------------------------------------
echo(
echo(按任意键退出...
pause >nul
exit /b 0
